Меньшие объекты наверх

[Artur_V]

Доброго!

Существует ли такой макрос чтоб из кучи выделенных объектов располагал на самом верху наименьшие?
вот чтоб как на картинке в аттаче.

ну или может кто подскажет как его сделать.
спасибо

 

[wOxxOm]

Ответ: Меньшие объекты наверх

есть wx.selectSmallObjects, который выделяет в куче все меньшие заданного значения (потом можно их выдернуть наверх ессно), а сортировщика по размеру не видел. А почему бы не создать заново например блендом или еще как?

P.S. если есть желание писать самому, - подскажу

 

[lev]

Ответ: Меньшие объекты наверх

Вот пример макроса от Hendrik Wagenaar, сортировка идёт по площади

Option Explicit

' This function sorts the order of objects based on the objects area.  Largest objects
' will be pushed to the back while smaller objects will be placed in front.
Private Sub BubbleSortByArea(ByVal sr As ShapeRange)
    Dim n1 As Long              ' inner loop index
    Dim n2 As Long              ' outer loop index
    Dim swap As Integer         ' temp variable
    Dim aofi() As Integer       ' Array of indices to sort
    ReDim aofi(1 To sr.Count)   ' Allocate

    ' fill the array with numbers 1 to the number of object
    For n1 = 1 To sr.Count
        aofi(n1) = n1
    Next n1

    ' perform the sort of the indices
    For n2 = 1 To sr.Count - 1
        For n1 = n2 + 1 To sr.Count
            If sr(aofi(n1)).DisplayCurve.Area > sr(aofi(n2)).DisplayCurve.Area Then
                swap = aofi(n1)
                aofi(n1) = aofi(n2)
                aofi(n2) = swap
            End If
        Next n1
    Next n2

    ' order the objects based on the area
    For n1 = 1 To sr.Count
        sr(aofi(n1)).OrderToFront
    Next n1

End Sub

Sub Sort()
BubbleSortByArea ActivePage.Shapes.All
End Sub

 

[Artur_V]

Ответ: Меньшие объекты наверх

wOxxOm спасибо, wx.selectSmallObjects и использовал для этой цели, как раз после бленда и надо все разместить, объектов много (в атаче приложил кусочек того что делаю).
lev спасибо, попробую разобраться.