[CDR X5-X8] удаление hidden locked SVG data

[qzmin]

Помогите, пожалуйста, сделать макрос для избавления от скрытых и залоченых объектов SVG data по всему документу, в том числе в группах и поверклипах.

Поиски выдали конструкции:

ActivePage.Shapes.FindShapes(Query:="@COM.locked = true").Unlock
ActivePage.Shapes.FindShapes(Query:="@COM.visible = false").Show

но моих познаний не хватает, чтобы заставить их обрабатывать группы и поверклипы в различных комбинациях и степенях вложения.

 

[_MBK_]

заставить их обрабатывать группы и поверклипы в различных комбинациях и степенях вложения.

А это и невозможно в общем случае
Буквально на днях была тема здесь - скриптинг принципиально не видит некоторые шейпы в масках и клипах

 

[lev]

Если только группы и клипы (бывают и другие виды вложения), то примерно так:

Sub Unlocker()
  On Error Resume Next
  ActiveDocument.BeginCommandGroup "Unlock all"
  Dim p As Page
  For Each p In ActiveDocument.Pages
    P_unlock p.Shapes
  Next p
  ActiveDocument.EndCommandGroup
End Sub

Private Sub P_unlock(sr As Shapes)
    Dim s As Shape
    For Each s In sr
        If s.Type = cdrGroupShape Then P_unlock s.Shapes
        If Not s.PowerClip Is Nothing Then P_unlock s.PowerClip.Shapes
    Next s
    sr.FindShapes(Query:="@COM.locked = true").Unlock
    sr.FindShapes(Query:="@COM.visible = false").Show
End Sub

 

[_MBK_]

Тьфу черт, совсем у меня от температуры мозги расплавились - думал тема про иллюстратор!

 

[qzmin]

lev, всё прекрасно показывает и разлочивает.
а как теперь удалить эти объекты?

sr.FindShapes(Query:="@type = 'хрень'").Delete ?

 

[_MBK_]

По идее да
А type тут при чем?

 

[qzmin]

_MBK_, просто sr.FindShapes.Delete удаляет объект наиглубше вложенный/загруппированный

 

[_MBK_]

То есть всю группу?
А разве можно выборочно заблокировать один объект в группе, не блокируя ее целиком?

 

[qzmin]

вот что делает скрипт

думаю вполне возможна и обратка

 

[_MBK_]

Так я не понял - вам надо что - SVG дата удалить целиком или только невидимые-заблокированные?

 

[qzmin]

конечная цель — удалить все объекты SVG data (что и было написано в начале).

 

[_MBK_]

А скопом и не получится
Вы обратили внимание, что за массив возвращает sr.FindShapes(...)? Там, по странному капризу канадских индусов, все шейпы, находящиеся в сожительстве с найденными. В Львином макросе работает только потому, что все сопутствующие объекты тоже видимы и разлочены
Нужно брать все шейпы на странице и перебирать их в цикле, проверяя на тип
Иначе никак

 

[lev]

конечная цель — удалить все объекты SVG data (что и было написано в начале).

В начале было написано удалить только скрытые и залоченные. На Вашем скрине присутствуют и нескрытые разлоченные SVG data.
Если нужно удалять все SVG data, я бы попробовал удалять шейпы по имени, а не типу и т.п.
Вы бы лучше небольшой подопытный файлик приложили, чтобы самому тесты не городить, время не тратить.

 

[_MBK_]

По любому одной командой FindShapes это не реализуется

 

[dosp]

В начале было написано удалить только скрытые и залоченные

Я справлялся с залоченными так: Создаю новый слой, Ctrl+A, перетаскиваю на новый слой, старый слой убиваю.

 

[qzmin]

Вы бы лучше небольшой подопытный файлик приложили, чтобы самому тесты не городить, время не тратить.

вот

 

[_MBK_]

По идее, корректным является следующий код

Sub Remover()
  On Error Resume Next
  ActiveDocument.BeginCommandGroup "Remove SVG data"
  Dim p As Page
  For Each p In ActiveDocument.Pages
    P_unlock p.Shapes
  Next p
  ActiveDocument.EndCommandGroup
End Sub

Private Sub P_unlock(sr As Shapes)
    Dim s As Shape
    For i = sr.Count To 1 Step -1
        Set s = sr.Item(i)
        If s.Type = cdrGroupShape Then P_unlock s.Shapes
        If Not s.PowerClip Is Nothing Then P_unlock s.PowerClip.Shapes
        If s.Type = cdrNoneShape Then
        
          s.Locked = False
          s.Delete
        End If
    Next i
  
End Sub

И этот код работает, правда, по непонятной причине, с первого раза все объекты не удаляет, нужно прогонять повторно.

 

[lev]

Интернеты для избавления от "SVG data" посоветовали сохранение в *.cmx. На тесте сработало. Можно и другие форматы попробовать.
Если у Вас многостраничник, или хочется одной кнопкой, то можно автоматизировать постраничный экспорт-реимпорт

 

[_MBK_]

А что думаешь по поводу

с первого раза все объекты не удаляет, нужно прогонять повторно.

?

 

[lev]

А что думаешь по поводу

опечатка в cdrNoneShape (не влияющая)
Стоит не удалять сразу, а собрать в коллекцию для последующего удаления сразу всех, тогда можно ещё и не заморачиваться с обратным циклом

Dim ss As New ShapeRange
Sub Remover()
    On Error Resume Next
    ActiveDocument.BeginCommandGroup "Remove SVG data"
    Dim p As Page
    For Each p In ActiveDocument.Pages
        P_unlock p.Shapes
    Next p
    ss.Delete
    ActiveDocument.EndCommandGroup
End Sub

Private Sub P_unlock(sr As Shapes)
    Dim s As Shape
    For Each s In sr
        If s.Type = cdrGroupShape Then P_unlock s.Shapes
        If Not s.PowerClip Is Nothing Then P_unlock s.PowerClip.Shapes
        If s.Type = cdrNoShape Then
            s.Locked = False
            ss.Add s
        End If
    Next
End Sub

Код оставляет невидимые или залоченные объекты не являющиеся "SVG data" (я уже запутался, как нужно ТС, можно добавить в код и их удаление), а cmx фокусы гробят их сразу.