VBA - Overprint black при экспорте в растр

[Sanchos]

Немогу создать тему, выдает ошибку.
Поэтому пишу здесь так как надо срочно...

как включить Оверпринт блэк вот для этого:?

Sub exportTifColir() 'Экспорт выделенного в TIF CMYK
    Dim d As Document, s As Shape, ex As ExportFilter, p As String
    Set d = CorelDRAW.ActiveDocument
    Set s = CorelDRAW.ActiveDocument.ActiveShape
    If s Is Nothing Then
        MsgBox "Ничего не выделено!"
        Exit Sub
    End If
    p = "R:\Work\!!!Rezonans\Links_maket\"
    p = p & "\" & Left(CorelDRAW.ActiveDocument.FileName, 11) & "_Color" & ".tif"
    
    Set ex = d.ExportBitmap(p, cdrTIFF, cdrSelection, cdrCMYKColorImage, , _
        , 300, 300, cdrNormalAntiAliasing, , False, True, False, cdrCompressionLZW)
    ex.Finish
End Sub

заранее спасибо

 

[Sanchos]

Ответ: Работа с Fountain из макроса под ХЗ

так не работает

Sub exportTifColir() 'Экспорт выделенного в TIF CMYK
    Dim d As Document, s As Shape, ex As ExportFilter, p As String
    Dim opt As New StructExportOptions
    Set d = CorelDRAW.ActiveDocument
    Set s = CorelDRAW.ActiveDocument.ActiveShape
    If s Is Nothing Then
        MsgBox "Ничего не выделено!"
        Exit Sub
    End If
    p = "R:\Work\!!!Rezonans\Links_maket\"
    p = p & "\" & Left(CorelDRAW.ActiveDocument.FileName, 11) & "_Color" & ".tif"
    
    With opt
    .AntiAliasingType = cdrNormalAntiAliasing
    .Compression = cdrCompressionLZW
    .ImageType = cdrCMYKColorImage
    .ResolutionX = 300
    .ResolutionY = 300
    .MaintainLayers = False
    .Transparent = False
    .UseColorProfile = True
    .OverprintBlack = True
    End With
    
    Set ex = d.ExportEx(p, cdrTIFF, cdrSelection, opt)
    ex.Finish
End Sub

 

[dizzy]

Ответ: Работа с Fountain из макроса под ХЗ

Старый баг... При экспорте в тиф через VBA в коде не предусмотрена возможность оверпринта по черному. Я об этом писал в корел, однак так и не поправили. Поэтому приходится перед экспортом растрировать выделение с оверпринтом, а уж потом экспортировать. Затем отмена... Пока так...

 

[Sanchos]

Ответ: VBA - Overprint black при экспорте в растр

Спасибо

 

[leechdraw]

Ответ: VBA - Overprint black при экспорте в растр

Ну если кому-то понадобится то вот такой вот скрипт получился у меня для решения этой задачи:

Dim fn As String
Dim eo As StructExportOptions
Set eo = New StructExportOptions
eo.AntiAliasingType = cdrNormalAntiAliasing
eo.Compression = cdrCompressionNone
eo.Dithered = False
eo.ImageType = cdrCMYKColorImage
eo.MaintainAspect = False
eo.MaintainLayers = False
eo.ResolutionX = 300
eo.ResolutionY = 300
eo.Transparent = False
eo.UseColorProfile = False
eo.Overwrite = True
dim k as integer
k=1
eo.SizeX = ConvertUnits(180, cdrMillimeter, cdrPixel) / k
eo.SizeY = ConvertUnits(70, cdrMillimeter, cdrPixel) / k
Application.ActiveDocument.PrintSettings.Separations.AlwaysOverprintBlack = True
Application.ActiveDocument.Selection.ConvertToBitmapEx cdrCMYKColorImage, False, False, 300, cdrNormalAntiAliasing, False, True
fn = "c:\my.tif"
Set Filter = Application.ActiveDocument.ExportEx(fn, cdrTIFF, cdrSelection, eo)
Filter.Finish
Application.ActiveDocument.Undo

небольшой комментарий:
k - это коэффициент для учета dpi при переводе из миллиметров в пиксели. Просто я так и не понял откуда ConvertUnits берет сведения о том сколько в одном миллиметре пикселей, но у меня он пересчитывает из расчета на 300 dpi. если требуется выставить

eo.ResolutionX = [B]150[/B]
eo.ResolutionY = [B]150[/B]

то есть 150 dpi то k я ставил равным 2.
Вот так вот.
Да кстати натыкался на одном из форумов, что

Application.ActiveDocument.PrintSettings.Separations.AlwaysOverprintBlack = True

а точнее аналогичная галочка при конвертации в битмап делает оверпринтом все составляющие, но у меня (CorelDraw X3) все нормально делалось, то есть оверпринтом вставал только черный.

 

[leechdraw]

Ответ: VBA - Overprint black при экспорте в растр

Ой... что-то не то с кодом.
Слова
Separatio ns
СonvertToBitm apEx
Пишутся конечно вот так:
СonvertToBitmapEx
Separations

 

[lev]

Ответ: VBA - Overprint black при экспорте в растр

Комментарий модератора: В данной ветке скриптами называют программы *.csc написанные на языке CorelSCRIPT. Программы на VBA называют макросами

 

[leechdraw]

Ответ: VBA - Overprint black при экспорте в растр

Спасибо буду знать. К сожалению не могу исправить( не вижу кнопку редактировать.