Запуск javascript скрипта из под Windows.

[trm1989]

Есть скрипт на javascript для InDesign нужно его запускать какимнибуть exe файлом.... можете чтонибуть посоветовать? Сейчас запускаю через Adobe ExtendScript Toolkit.

 

[_MBK_]

Ответ: Запуск javascript скрипта из под Windows.

То есть запустить скрипт от InDesign без InDesign? А смысл такого действия какой?

 

[trm1989]

Ответ: Запуск javascript скрипта из под Windows.

То есть запустить скрипт от InDesign без InDesign? А смысл такого действия какой?

Что бы не приходилось различным клиентам обьяснять что им нужно откуда-то скрипт запускать... это можно через VBscript cделать, правдо пока не до конца получилось.

Set myInDesign = CreateObject("InDesign.Application")
myJavaScript = "C:/indd/ready.jsx"
myInDesign.DoScript(myJavaScript,ScriptLanguage.JAVASCRIPT)

На последнюю строчку ругается...

 

[trm1989]

Ответ: Запуск javascript скрипта из под Windows.

Set myInDesign = CreateObject("InDesign.Application")
myJavaScript = "alert('1');"
myInDesign.DoScript myJavaScript, idScriptLanguage.idJavascript

Беру код из официального мануала - пишет ошибку на последнюю строчку - "object required idScriptLanguage"
Что я делаю не так?

 

[LeshikSan]

Ответ: Запуск javascript скрипта из под Windows.

потому что энумератор нужно использовать, а не ScriptLanguage.JAVASCRIPT

Вот портабельное решение, в vbs-скрипте нужно только имя jsx-скрипта указать

JSX_SCRIPT_NAME = "myScript.jsx"
main

Function main()
	Dim VBSScriptFolderFullName, JSXScriptFileFullName
	On Error Resume Next
	
	' Получаем путь в папку текущего скрипта
	Dim WshShell, objShell, objDialogFolder, objDialogFolderItem
	Set WshShell = CreateObject("WScript.Shell")
	 Set objShell = CreateObject("Shell.Application")  
	 Set objDialogFolder = objShell.Namespace(WshShell.CurrentDirectory)
	 Set objDialogFolderItem = objDialogFolder.Self
	VBSScriptFolderFullName = objDialogFolderItem.Path
	' Получаем путь к JSX-скрипту
	JSXScriptFileFullName = VBSScriptFolderFullName & "/" & JSX_SCRIPT_NAME
	' Проверяем наличие файла
	Set FSO = CreateObject("Scripting.FileSystemObject") 
	If Not FSO.FileExists(JSXScriptFileFullName) Then 
		MsgBox ("VBS: Файл " & JSXScriptFileFullName & " не существует") 
		Exit Function
	End If
	' Запускаем скрипт
	Set myInDesign = CreateObject("InDesign.Application")
	myInDesign.DoScript JSXScriptFileFullName, 1246973031
	
	' Обработка ошибок
	If Err.Number<>0 Then
		MsgBox "Ошбка: " & Err.Description & Err.Number
	End If
	On Error GoTo 0
End Function

 

[trm1989]

Ответ: Запуск javascript скрипта из под Windows.

LeshikSan , cпасибо - помогло...

jsFile = "C:\indd\ready.jsx"
Set myInDesign = CreateObject("InDesign.Application")
myInDesign.DoScript jsFile, 1246973031

если кому-то надо будет, просто - упростил.