Public Function ean13(chaine)
Dim i%, checksum%, first%, CodeBarre$, tableA As Boolean
ean13 = ""
' checking that all characters in the barcode are digits
For i% = 1 To Len(chaine)
If Asc(Mid$(chaine, i%, 1)) < 48 Or Asc(Mid$(chaine, i%, 1)) > 57 Then
ean13 = ""
Exit Function
End If
Next
' Calculating the check digit
If Len(chaine) = 12 Then
For i% = 2 To 12 Step 2
checksum% = checksum% + Val(Mid$(chaine, i%, 1))
Next
checksum% = checksum% * 3
For i% = 1 To 11 Step 2
checksum% = checksum% + Val(Mid$(chaine, i%, 1))
Next
chaine = chaine & (10 - checksum% Mod 10) Mod 10
End If
' developing the barcode string
If Len(chaine) = 13 Then
' The first number is taken as is, the second is from Table A
CodeBarre$ = Left$(chaine, 1) & Chr$(65 + Val(Mid$(chaine, 2, 1)))
first% = Val(Left$(chaine, 1))
For i% = 3 To 7
tableA = False
Select Case i%
Case 3
Select Case first%
Case 0 To 3
tableA = True
End Select
Case 4
Select Case first%
Case 0, 4, 7, 8
tableA = True
End Select
Case 5
Select Case first%
Case 0, 1, 4, 5, 9
tableA = True
End Select
Case 6
Select Case first%
Case 0, 2, 5, 6, 7
tableA = True
End Select
Case 7
Select Case first%
Case 0, 3, 6, 8, 9
tableA = True
End Select
End Select
If tableA Then
CodeBarre$ = CodeBarre$ & Chr$(65 + Val(Mid$(chaine, i%, 1)))
Else
CodeBarre$ = CodeBarre$ & Chr$(75 + Val(Mid$(chaine, i%, 1)))
End If
Next
CodeBarre$ = CodeBarre$ & "*" 'Adding central divider
For i% = 8 To 13
CodeBarre$ = CodeBarre$ & Chr$(97 + Val(Mid$(chaine, i%, 1)))
Next
CodeBarre$ = CodeBarre$ & "+" 'adding the terminating char
ean13 = CodeBarre$
End If
End Function
